-- SHOW LOCALIZED MEMBER --
--
-- © December 2000, James Newton <newton@planetb.fr>
--
-- Changes the member of the current sprite according to the language
-- defined by (in decreasing order of importance):
-- * (the globals)[#gUserLanguage]
-- * (the environment)[#osLanguage]
-- * (the environment)[#uiLanguage]
--
-- For simplicity, the case statement in the beginSprite() handler
-- uses hardcoded castLib names.  You may need to alter these to suit
-- your own project.



-- SPRITE EVENT --

on beginSprite(me)
  userLanguage = (the globals)[#gUserLanguage]
  
  if voidP(userLanguage) then
    -- Try to use the system language (D8 only) ... 
    environmentData = the environment
    userLanguage = environmentData[#osLanguage]
    if voidP(userLanguage) then
      -- ... or failing that, the language the movie was developed in
      userLanguage = environmentData[#uiLanguage]
    end if
  end if
  
  -- Determine which castLib to use
  case userLanguage of -- CAUTION: Hardcoded castLib names
    "French", "Français": castLibNumber = castLib("French").number
      -- Add other languages here
      
    otherwise
      -- The chosen language is not supported, use English instead
      castLibNumber = castLib("English").number
  end case
  
  -- Use the member from the appropriate castLib 
  thisSprite = sprite(me.spriteNum)
  memberNumber = thisSprite.memberNum
  thisSprite.member = member(memberNumber, castLibNumber)
end beginSprite



-- BEHAVIOR DESCRIPTION AND PARAMETERS --

on isOKToAttach(me, spriteType, spriteNumber)
  -- Prevent the behavior from attaching itself to the frame
  return spriteType = #graphic
end isOKToAttach



on getBehaviorTooltip(me)
  return \
"Changes the member of the current sprite"&RETURN&\
"according to the language defined by"&RETURN&\
"(in decreasing order of importance):"&RETURN&\
" * (the globals)[#gUserLanguage]"&RETURN&\
" * (the environment)[#osLanguage]"&RETURN&\
" * (the environment)[#uiLanguage]"
end getBehaviorTooltip



on getBehaviorDescription(me)
  return \
"SHOW LOCALIZED MEMBER"&RETURN&RETURN&\
"Changes the member of the current sprite according to the language defined by (in decreasing order of importance):"&RETURN&\
" * (the globals)[#gUserLanguage]"&RETURN&\
" * (the environment)[#osLanguage]"&RETURN&\
" * (the environment)[#uiLanguage]"&RETURN&RETURN&\
"CastLib names in the beginSprite() handler are hard-coded: you should change these to suit your project."
end getBehaviorTooltip